返回列表 发帖
DoubleW

Rank: 3Rank: 3

帖子
56 
积分
187 
威望
229  
金钱
160  
在线时间
17 小时 

高手勋章VIP会员核心成员贡献奖内部成员帅哥勋章支持奖章突出贡献奖论坛元老技术组成员
1楼 跳转到 » 倒序看帖
打印
tT
发表于 2008-7-2 09:41 | 只看该作者

【转】for的用法【批处理】

批处理, 用法
有的时候批处理对我们来说是相当好用的，效率高，也方便。下面是在网上找的一些资料，希望对大家会有一点的帮助。以下是转自mybat论坛的for命令用法：



for命令教学                                                                                                                                                                                                                                                                                                                       
对所有的批处理初学者来说，for的应用是最难理解以及掌握的。本文由浅入深，为大家专门讲解for的用法，希望大家喜

欢。

首先应该明确的是,for不是一个简单的命令，它的用法比较复杂,它还可以带四个参数(/L /D /R /F),其中:/L和/F参数是

最经常用到的。当然，它本身也可以不带参数，下面我们通过具体的例子来讲解for的运用。

一、不带参数的for：
让我们先来看一个示例：
代码:@echo off
for %%i in (1 2 3 4 5) do echo %%i
pause
将以上代码保存为批处理文件(如何保存?)，然后运行，可以发现屏幕上显示1 2 3 4 5(每字一行)
是不是明白了一些？它的整个运行机制我们可以这样看：for不停的从括号中拿出5个“东西”来（以空格做间隔），并将这5个“东西”依次传给临时变量%%i，同时把这个变量echo出来....

从这个例子我们可以看出，for的基本用法是：
for 变量 in (目标) do 干什么?

变量常用%%i 来表示，当然也可以换成%%j；目标就是待处理的对象集合，比如这里的1 2 3 4 5；这里的干什么的内容为：批处理命令。
【相关习题：】将你的名字用for命令分三行显示出来！！！

二、带参数 /L 的for (这里的 参数/L 可以理解为 "list" 的意思，代表一个数列)
先看测试代码：

@echo off
for /l %%i in (1 1 5) do echo %%i
pause
显示结果也为：1 2 3 4 5(每字一行)
它的意思和上面的意思差不多，但是括号中的对象却不需要 写成 1 2 3 4 5 的形式了，而是：1 1 5，因为它启用了参数 /L，就是告诉for，这个括号里的对象是个数列，怎样的数列？就是以 1 开始，步长 为1 ，结束值为5的一个等差数列，再举个实例：复制内容到剪贴板代码:::显示 从 10 - 20 的所有偶数：
@echo off
for /l %%i in (10 2 20) do echo %%i
pause
【相关习题：】显示 1~20 间能被5整 除的整数
收藏 分享

DoubleW

Rank: 3Rank: 3

帖子
56 
积分
187 
威望
229  
金钱
160  
在线时间
17 小时 

高手勋章VIP会员核心成员贡献奖内部成员帅哥勋章支持奖章突出贡献奖论坛元老技术组成员
2楼
发表于 2008-7-2 09:42 | 只看该作者
for命令 在dos命令中,不算最复杂的也应该算是相当复杂的了,而for的参数中又以 /f 参数最为复杂,难懂和常用.
在刚学时确实费了我不少脑筋,下面就我个人的理解,给新手们通俗的讲讲,也好让新手少走些弯路.
格式:
::例一:
代码:

for /f "skip=1 tokens=1,2* delims= " %%a in (a.txt) do echo %%a %%b %%c
pause
先从引号内的东西讲起,很多新手对这些难以理解,因为 for /? 翻译的简直是一塌糊涂.
skip=
tokens=
delims=
这三项是用的最多的,根据需要.可以不用,可以一起使用,也可以只使用一个或两个.
但是不管使用几个都要用引号将它们扩起来.当然不使用时,自然就不需要引号了.
skip=
for循环文本内容是以行为单位,从上至下进行的,skip=1意识就是跳过文本的第一行,即不循环第一行
那么skip=2 自然就是跳过前两行了,依次类推.........

delims=
先讲这句
delims=后面的字符的意识是,将文本每一行的内容以delims=后面的字符分割成若干列.
假设a.txt某一行的内容是 111,222.333 444/555
我们用下面的语句
::例二:
代码:

for /f "tokens=1-5 delims=,./ " %%a in (a.txt) do echo %%a %%b %%c %%d %%e
pause
显示结果是 111 222 333 444 555
解释:
  意识就是把111,222.333 444/555以,./和空格(不分先后)分成了5列.注意代码中/和"后面有个空格,
  使用中要注意空格要放到最后,如"delims=,. /" 这样就不行了.
那如果我们不使用逗号来分割会如何呢?如: "delims=./ "那么就会分割成111,222 333 444 555
看出区别了吗?delims=后面可以是多个字符,可以是空格,也可以什么都没有.
什么都没有代表什么呢?就是不以任何东西为分割符,也是整行的内容了.
因为for默认是以,;和空格作分割符的,
所以一般要取得整行内容通常会用"delims="这样的形式来取消for的默认分割符.

tokens=
tokens=1-5
1-5很好理解就1至5,前面我们用delims=后面的字符为分割符,将文本内容分成了多列,那么你需要的是哪些列呢?
用tokens=可以很好帮你提取到.
还是以例二为例:
通过dilims=,./  将文本分成了111 222 333 444 555 五列.
注意代码中前面有个%%a 这里的%%a就是代表第一列,第二列就是%%b,第三列就是%%c 依此类推.....
那么我们如果把echo %%a %%b %%c %%d %%e 改为 echo %%e %%d %%c %%b %%a 会如何呢?
当然.会显示 555 444 333 222 111
如果是:echo %%b %%d 又会显示什么呢?  不用我说了吧!
若是第一个%%a把它改为%%i也是一样,那么第二列就是%%j...%%k...依此类推....
明白了?就是按英文字母的顺序依此类推的.
这里我们用的是tokens=1-5但是在例一中,我们用的是tokens=1,2* 有什么区别呢?
其实差不多-号代表从几至几而逗号代表单一的,如 tokens=1,5就是代表第一列和第五列,而不是1至5列.
*号代表剩下的所有的列.如:tokens=1,2*代表%%a为第一列,%%b为第二列,%%c代表后面所有的列.

for /f 不但可以循环文本内容还可以循环字符窜,如:
::例三:
代码:

for /f "tokens=1-3 delims=,./ " %%a in ("111,222.333 444/555") do echo %%a %%b %%c
pause
只要将()里的字符串用引号扩起来,for就会把它当字符串来循环,而不是文本.

TOP

DoubleW

Rank: 3Rank: 3

帖子
56 
积分
187 
威望
229  
金钱
160  
在线时间
17 小时 

高手勋章VIP会员核心成员贡献奖内部成员帅哥勋章支持奖章突出贡献奖论坛元老技术组成员
3楼
发表于 2008-7-2 09:43 | 只看该作者
这篇文章是网上找的，很多初学DOS的朋友对FOR语句掌握的好不是太过熟悉，希望这边文章能够给你开阔思路帮助你把FOR语句学好，主要的参数介绍和实例讲的都很清楚，也希望对DOS越来越感兴趣－－－＞发挥你的想像力吧

　　　　　　　　　　　　　　　正文开始

以前常觉得DOS的命令行功能太弱，无法象UNIX一样可以用命令行完成非常复杂的操作。实际上，当MS从WIN2K开始将命令行增强后，已经借鉴了相当多UNIX的优点，虽然还无法做到象UNIX那么灵活，但已可完成绝大多数的任务，比如用&&和　　连接两个（或更多）命令，由前一个的返回值来决定下一个是否执行，等等。而在这些增强中，最明显的，就是FOR命令。
举个例子，用适当的参数，可用FOR命令将 date /t 的输出 从 "Sat 07/13/2002" 变成你想要的格式，比如， "2002-07-13"：

c:\>for /f "tokens=2,3,4 delims=/ " %a in ('date /t') do @echo %c-%a-%b
2002-07-13

该例将在（3）中详细说明。
0. 基本应用
简单说，FOR是个循环，可以用你指定的循环范围生成一系列命令。最简单的例子，就是人工指定循环范围，然后对每个值执行指定的命令。例如，想快速报告每个硬盘分区的剩余空间：

for %a in (c: d: e: f do @dir %a\ 　 find "bytes free"

将输出：

8 Dir(s) 1,361,334,272 bytes free
15 Dir(s) 8,505,581,568 bytes free
12 Dir(s) 12,975,149,056 bytes free
7 Dir(s) 11,658,854,400 bytes free

用它可以使一些不支持通配符的命令对一系列文件进行操作。在WIN9X中，TYPE命令（显示文件内容）是不支持*.txt这种格式的（WIN2K开始TYPE已支持通配）。遇到类似情况就可以用FOR：

for %a in (*.txt) do type %a

这些还不是FOR最强大的功能。我认为它最强大的功能，表现在以下这些高级应用：

1. 可以用 /r 参数遍历整个目录树
2. 可以用 /f 参数将文本文件内容作为循环范围
3. 可以用 /f 参数将某一命令执行结果作为循环范围
4. 可以用 %~ 操作符将文件名分离成文件名、扩展名、盘符等独立部分

现分别举例说明如下：
1. 用 /r 遍历目录树
当用 *.* 或 *.txt 等文件名通配符作为 for /r的循环范围时，可以对当前目录下所有文件（包括子目录里面的文件）进行操作。举个例子，你想在当前目录的所有txt文件（包括子目录）内容中查找"bluebear"字样，但由于find本身不能遍历子目录，所以我们用for:

for /r . %a in (*.txt) do @find "bluebear" %a

find 前面的 @ 只是让输出结果不包括 find 命令本身。这是DOS很早就有的功能。和FOR无关。
当用 . 作为循环范围时，for 只将子目录的结构（目录名）作为循环范围，而不包括里面的文件。有点象 TREE 命令，不过侧重点不同。TREE的重点是用很漂亮易读的格式输出，而FOR的输出适合一些自动任务，例如，我们都知道用CVS管理的项目中，每个子目录下都会有一个CVS目录，有时在软件发行时我们想把这些CVS目录全部去掉：

for /r . %a in (.) do @if exist %a\CVS rd /s /q %a\CVS

先用 if exist 判断一下，是因为 for 只是机械的对每个目录进行列举，如果有些目录下面没有CVS也会被执行到。用 if exist 判断一下比较安全。
这种删除命令威力太大，请小心使用。最好是在真正执行以上的删除命令前，将 rd /s /q 换成 @echo 先列出要删出的目录，确认无误后再换回rd /s /q：

for /r . %a in (.) do @if exist %a\CVS @echo %a\CVS

可能目录中会多出一层 "."，比如 c:\proj\release\.\CVS ，但不会影响命令的执行效果。
2. 将某一文件内容或命令执行结果作为循环范围：
假如你有一个文件 todel.txt，里面是所有要删除的文件列表，现在你想将里面列出的每个文件都删掉。假设这个文件是每个文件名占一行，象这样：

c:\temp\a1.txt
c:\temp\a2.txt
c:\temp\subdir\b3.txt
c:\temp\subdir\b4.txt

那么可以用FOR来完成：

for /f %a in (todel.txt) do del %a

这个命令还可以更强大。比如你的 todel.txt 并不是象上面例子那么干净，而是由DIR直接生成，有一些没用的信息，比如这样：

Volume in drive D is DATA
Volume Serial Number is C47C-9908
Directory of D:\tmp
09/26/2001 12:50 PM 18,426 alg0925.txt
12/02/2001 04:29 AM 795 bsample.txt
04/11/2002 04:18 AM 2,043 invitation.txt
4 File(s) 25,651 bytes
0 Dir(s) 4,060,700,672 bytes free

for 仍然可以解出其中的文件名并进行操作：

for /f "skip=5 tokens=5" %a in (todel.txt) do @if exist %a DEL %a

当然，上面这个命令是在进行删除，如果你只是想看看哪些文件将被操作，把DEL换成echo:

for /f "skip=5 tokens=5" %a in (todel.txt) do @if exist %a echo %a

你将看到：

alg0925.txt
bsample.txt
invitation.txt

skip=5表示跳过前5行（就是DIR输出的头部信息），tokens=5表示将每行的第5列作为循环值放入%a，正好是文件名。在这里我加了一个文件存在判断，是因为最后一行的"free"刚好也是第5列，目前还想不出好的办法来滤掉最后两行，所以检查一下可保万无一失。
3. 可以用 /f 参数将某一命令执行结果作为循环范围
非常有用的功能。比如，我们想知道目前的环境变量有哪些名字（我们只要名字，不要值）。可是SET命令的输出是“名字=值”的格式，现在可以用FOR来只取得名字部分：

FOR /F "delims==" %i IN ('set') DO @echo %i

将看到：

ALLUSERSPROFILE
APPDATA
CLASSPATH
CommonProgramFiles
COMPUTERNAME
ComSpec
dircmd
HOMEDRIVE
......

这里是将set命令执行的结果拿来作为循环范围。delims==表示用=作为分隔符，由于FOR /F默认是用每行第一个TOKEN，所以可以分离出变量名。如果是想仅列出值：

FOR /F "delims== tokens=2" %i IN ('set') DO @echo %i

tokens=2和前例相同，表示将第二列（由=作为分隔符）作为循环值。
再来个更有用的例子：
我们知道 date /t （/t表示不要询问用户输入）的输出是象这样的：

Sat 07/13/2002

现在我想分离出日期部分，也就是13：

for /f "tokens=3 delims=/ " %a in ('date /t') do @echo %a

实际上把 tokens后面换成1,2,3或4，你将分别得到Sat, 07, 13和2002。注意delims=/后面还有个空格，表示/和空格都是分隔符。由于这个空格delims必须是/f选项的最后一项。
再灵活一点，象本文开头提到的，将日期用2002-07-13的格式输出：

for /f "tokens=2,3,4 delims=/ " %a in ('date /t') do @echo %c-%a-%b

当tokens后跟多个值时，将分别映射到%a, %b, %c等。实际上跟你指定的变量有关，如果你指定的是 %i, 它们就会用%i, %j, %k等。
灵活应用这一点，几乎没有做不了的事。
4. 可以用 %~ 操作符将文件名分离成文件名、扩展名、盘符等独立部分
这个比较简单，就是说将循环变量的值自动分离成只要文件名，只要扩展名，或只要盘符等等。
例：要将 c:\mp3下所有mp3的歌名列出，如果用一般的 dir /b/s 或 for /r ，将会是这样：

g:\mp3\Archived\05-18-01-A\游鸿明-下沙\游鸿明-01 下沙.mp3
g:\mp3\Archived\05-18-01-A\游鸿明-下沙\游鸿明-02 21个人.mp3
......
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-阿修罗.mp3
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-彼岸花.mp3
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-不爱我的我不爱.mp3
......

如果我只要歌名（不要路径和".mp3"）：

游鸿明-01 下沙
游鸿明-02 21个人
......
王菲-阿修罗
王菲-彼岸花
王菲-不爱我的我不爱
......

那么可以用FOR命令：

for /r g:\mp3 %a in (*.mp3) do @echo %~na

凡是 %~ 开头的操作符，都是文件名的分离操作。具体请看 for /? 帮助。
本文举的例子有些可能没有实际用处，或可用其它办法完成。仅用于体现FOR可以不借助其它工具，仅用DOS命令组合，就可完成相当灵活的任务

TOP

返回列表